dann hilft nachfolgender Artikel, den ich am 13.7.2019 überarbeitet habe. Er basiert auf einer Anregung des Autors Wassenhofen im 2011 noch existierenden Picasa-Produktforum, das inzwischen nicht mehr online ist. Die dort zu seinem Beitrag vorfindlichen Erläuterungen waren allerdings so spärlich und verstreut, dass ich für die Verwendung unter Windows 7 bis 10 eine ausführliche und erprobte Schritt-für-Schritt-Anleitung dazu anbiete und eine Modifikation für Windows xp. Vor der Implementation auf Ihrem PC beachten Sie bitte die am Ende dieses Artikels abgegebene Erklärung zum Haftungsausschluss.
Grundlagen
Picasa 3 erstellt zur Fotosammlung auf dem PC eine Datenbank, in der die Speicherorte, Gesichtserkennungsergebnisse, vergebene Tags und Miniaturbilder mit den Fotodateien verknüpft sind. Diese Datenbank wird in zwei Ordnern namens "Picasa2" und "Picasa2Albums" gespeichert.
Unter Windows 7 - 10 legt eine lokale Installation von Picasa (im Ordner "C:\Program Files (x86)\Google\Picasa3") diese beiden Datenbank-Ordner automatisch als Unterordner in "C:\Users\'<'Benutzername'>'\AppData\Local\Google" an. Auf diesen Ordner hat nur der angegebene Benutzer Zugriff. Die Datenbank-Ordner lassen sich jedoch auf ein externes Laufwerk (z.B. auch in einem NAS) übertragen, so dass sie sowohl einen Systemwechsel (z.B. bei Neuaufsetzen des Rechners) überstehen als auch von jedem PC mit entsprechend installiertem Picasa-Programm für Anzeige und Bearbeitung verfügbar sind.
Vorbereitungen
Zuerst sorgt man dafür, dass das externe Laufwerk auf allen beteiligten PCs unter dem gleichen Laufwerksbuchstaben adressierbar ist, beispielsweise als Speicher für 'Medien' naheliegend mit dem Buchstaben "M:". Auf diesem Laufwerk, auf dem womöglich auch schon alle Fotos gespeichert sind, legt man dann im Root-Verzeichnis einen leeren Ordner (im Beispiel also "M:\Picasa-DB") an. Die Anlage des Verzeichnisses "M:\Picasa-DB\AppData\Local\Google" mit den beiden Datenbank-Unterordnern besorgt die nachfolgend beschriebene Batch-Datei bei ihrem ersten Aufruf (vgl. weiter unten). Danach muss man die Ordnerinhalte der beiden Datenbankordner aus dem lokalen Ordner "C:\Users\< Benutzername>\AppData\Local\Google" in den externen Ordner "M:\Picasa-DB\AppData\Local\Google" kopieren. Bei jedem folgenden Aufruf der Batchdatei startet dann Picasa 3 unter Verwendung der auf "M:\Picasa-DB" hinterlegten Datenbank. Dabei sorgt die Batchdatei auch dafür, dass (z.B. auf einem NAS-Laufwerk) nur jeweils ein Nutzer auf einem PC Zugriff bekommt.
Die Batch-Datei
Das englische Wort 'batch' bedeutet 'Stapel'. Jede Batch-Datei enthält einen Stapel von Befehlen, die vom jeweiligen Betriebssystem interpretiert und nacheinander ausgeführt werden. Die Befehle sind in einem Texteditor zeilenweise (ohne führende Zeilennummern) einzugeben. Abschließend wird die Text-Datei mit einem sprechenden Namen und einer charakteristischen Endung (in Windows ".bat" oder ".cmd") gespeichert., z.B. als "StartPicasa.bat". Als Zielordner für diese Batch-Datei kommt der Desktop jedes beteiligten PCs in Betracht oder - praktischer - das Stammverzeichnis des Laufwerks, auf dem die Fotos und das externe Datenbankprofil gespeichert werden, also z.B. "M:\". Der Aufruf der Batch-Datei erfolgt durch Doppelklick auf ihr Desktop-Icon (bzw. auf den Dateinamen "M:\StartPicasa.bat") . Danach öffnet sich ein Befehlskonsolenfenster auf dem Bildschirm, in dem die vorgesehenen Mitteilungen angezeigt werden. Dieses Konsolenfenster schließt nach Beendigung von Picasa automatisch. Es soll aber nicht vorher geschlossen werden!
Für den angegebenen Zweck hat die Batch-Datei folgenden Inhalt:
| Z. |
Befehl
Kommentar |
| 1 |
@echo off
Schaltet (sonst störende) Anzeige der Befehle im Befehlskonsolenfenster ab |
| 2 |
set EXTERNPROFILEPATH=M:\Picasa-DB
Hinterlegt den Speicherortnamen der externen Datenbank in einer Variablen |
| 3 |
set PICASAEXECPATH=C:\Program Files (x86)\Google\Picasa3\
Hinterlegt den Ordnerpfad, von dem aus "Picasa3.exe" gestartet wird, in einer Variablen |
| 4 |
set TEMPPATH="%EXTERNPROFILEPATH%\AppData\Local"
Hinterlegt den Ordnerpfad für die Zieldatenbank in einer Variablen |
| 5 |
if not exist %TEMPPATH% mkdir %TEMPPATH%
Falls der Zieldatenbankordner nicht existiert, wird er angelegt |
| 6 |
if not exist %TEMPPATH% goto NoValidPath
Falls der Zieldatenbankordner nicht existiert, wird er angelegt |
| 7 |
:: Uebergabevariable fuer den Aufruf von Picasa mit dem externen Profil
Notiz ("::" enspricht "REM") |
| 8 |
set USERPROFILE=%EXTERNPROFILEPATH%
Der Umgebungsvariablen USERPROFILE wird der Pfad mit dem externen Profil übergeben |
| 9 |
:: Pruefung, ob Picasa schon anderswo aufgerufen ist - sonst Sperre einrichten
Notiz |
| 10 |
set LOCKFILE="%EXTERNPROFILEPATH%\PicasaRunning.txt"
Name und Pfad für die Sperrdatei werden deklariert |
| 11 |
if exist %LOCKFILE% goto PicasaRunningAlready
Falls die Sperrdatei existiert, ist Picasa schon anderweitig aktiv (Sprung nach Zeile 27) |
| 12 |
echo Picasa ist schon gestartet von %USERNAME% am %date% um %time% auf Computer %COMPUTERNAME% > %LOCKFILE%
Andernfalls wird das Sperrfile mit dem angegebenen Inhalt erzeugt.
Achtung: Der gesamte Inhalt muss in eine Zeile geschrieben werden!
Das ">" - Zeichen veranlasst eine Umleitung der Ausgabe vom Bildschirm auf die dahinter angegebene Datei. |
| 13 |
:: Pruefung, ob Installationspfad fuer Picasa zutrifft - ggf. starten, sonst nicht
Notiz |
| 14 |
set TEMPPATH="%PICASAEXECPATH%"
Der Variablen TEMPPATH wird ein neuer Wert zugewiesen, um dieselbe Fehlermeldung wie zu Zeile 11 auch bei Nichtvorhandensein des Programmpfads verwenden zu können. |
| 15 |
if not exist %TEMPPATH% goto NoValidPath
Wenn der Installationspfad für Picasa nicht existiert, liegt ein Fehler vor (Sprung nach Zeile 33) |
| 16 |
:: Start Picasa...
Notiz |
| 17 |
echo PICASA wird jetzt im Profil von %EXTERNPROFILEPATH% ausgefuehrt.
Anzeige im Befehlskonsolenfenster |
| 18 |
echo ACHTUNG:
Anzeige im Befehlskonsolenfenster |
| 19 |
echo Dieses Fenster muss aktiv bleiben, solange mit PICASA gearbeitet wird;
Anzeige im Befehlskonsolenfenster |
| 20 |
echo sobald PICASA beendet wird, schliesst es von selbst.
Anzeige im Befehlskonsolenfenster |
| 21 |
cd %PICASAEXECPATH%
Der Programmpfad von picasa3.exe wird zum aktiven Ordner bestimmt |
| 22 |
"%PICASAEXECPATH%/Picasa3.exe"
Picasa3 wird aufgerufen |
| 23 |
:: Sperrdatei wird beseitigt ...
Notiz |
| 24 |
del %LOCKFILE%
Die Sperrdatei wird gelöscht |
| 25 |
goto eof
Ende der Batch-Bearbeitung |
| 26 |
:: Picasa ist anderweitig aufgerufen ...
Notiz |
| 27 |
:PicasaRunningAlready
Sprungmarke (von Zeile 11) |
| 28 |
echo Eine anderes Instanz von PICASA ist schon gestartet:
Anzeige im Befehlskonsolenfenster |
| 29 |
echo %USERNAME% nutzt sie seit %date% um %time% auf %COMPUTERNAME%.
Anzeige im Befehlskonsolenfenster |
| 30 |
pause
Aufforderung, nach Kenntnisnahme eine Taste zu betätigen |
| 31 |
goto eof
Ende der Batch-Bearbeitung |
| 32 |
:: Fehlermeldung, wenn der Pfad nicht existiert oder nicht erzeugt werden konnte
Notiz |
| 33 |
:NoValidPath
Sprungmarke (von Zeile 6 oder 15) |
| 34 |
echo FEHLER!
Anzeige im Befehlskonsolenfenster |
| 35 |
echo Der Pfad %TEMPPATH% ist nicht vorhanden oder konnte nicht erstellt werden.
Anzeige im Befehlskonsolenfenster |
| 36 |
pause
Aufforderung, nach Kenntnisnahme eine Taste zu betätigen |
| 37 |
goto eof
Ende der Batch-Bearbeitung |
Bei der Eingabe bzw. Kopie dieser Batchdatei in einen Texteditor ist unbedingt darauf zu achten, dass
- innerhalt einer Zeile kein Zeilenumbruch vorkommt, und dass
- an keinem Zeilenende Leerzeichen stehen.
Eine kopierfähige Textversion der o.a. Batch-Datei ist unten (im "Anhang") beigefügt.
Anpassung an eine frühere Windows-Version
Ersetzt man in der o.a. Batch-Datei die Zeile 4 durch
"set TEMPPATH="%PICASAPROFILEPATH%\Lokale Einstellungen\Anwendungsdaten",
(in eienr Zeile und ohne Anführungszeichen!)
so eignet sich die sonst gleiche Batch-Datei auch für Windows xp. Zudem sollte man kontrollieren, ob die Datei Picasa3.exe sich im angegebenen Installationsordner befindet und nötigenfalls auch Zeile 3 entsprechend anpassen.
Eine Batchdatei - unterschiedliche Wirkungen
Mit dem ersten Aufruf der Batch-Datei erscheint Picasa genauso wie nach seiner ersten Installation:
Nach dem vorübergehend sichtbaren Banner (Abb. 1) öffnen sich über der Programm-Oberfläche nacheinander die beiden Fenster zur Festlegung des Bereichs, aus dem Picasa Fotos einlesen soll (Abb. 2), und welche Arten von Bilddateien mit dem Picasa-Viewer verknüpft werden sollen (Konfiguration des Photo Viewer).
Abb. 2 - Suchorte für Bilder festlegen
Um die Wartezeit zu verkürzen, empfiehlt sich die zuoberst angebotene Option "Nur Eigene Dokumente … durchsuchen" durch Anklicken des Buttons auszuwählen. Bei der Frage nach den darzustellenden Bilddateitypen ist die Antwort beliebig; es liegt nahe, sie möglichst in Übereinstimmung mit der Setzung bei der Erstinstallation auszuwählen.
Danach legt Picasa die für die Datenbank automatisch erforderlichen Unterordner in der Profilumgebung "M:\Picasa-DB" an. Nun kann Picasa sogleich wieder geschlossen werden; das Konsolenfenster schließt sich danach automatisch.
Nachdem die beiden Picasa2-Ordner wie unter Vorbereitungen beschrieben in die Profilumgebung kopiert worden sind, führt der Aufruf derselben Batch-Datei nun wunschgemäß zum Aufruf von Picasa mit den dorthin kopierten Datenbanken. Dabei ist zu beachten, dass je nach Größe der Datenbanken die Zeit für das Laden und für das Schließen derselben einige Zeit beanspruchen kann, in der das Programm-Banner (Abb. 1) stehen bleibt bzw. sich das Programmfenster am Ende nicht sofort schließt.
Nutzungshinweise
Die Anlage des externen Profils hat keine Auswirkungen auf die lokale Installation von Picasa. Deswegen bleibt der Aufruf von Picasa3 weiterhin auch direkt (ohne Batchdatei) möglich. Die dabei vorgenommenen Veränderungen an der lokalen Datenbank bleiben jedoch ohne Auswirkung auf die externe Datenbank - und umgekehrt ebenso. Es empfiehlt sich deshalb, Picasa dann nur noch über die Batchdatei aufzurufen und das Programm-Icon von Picasa vom Desktop zu löschen, um Versehen aus Gewohnheit vorzubeugen.
Sollte - statt zuerst PICASA zu beenden - das Fenster die Batch-Datei vorzeitig beendet werden, wird die Sperrdatei nicht automatisch gelöscht. Dadurch verhindert der letzte Nutzer den erneuten Aufruf von PICASA mit dem externen Profil. In einem solchen Fall muss die Sperrdatei "M:\Picasa-DB\PicasaRunning.txt" manuell gelöscht werden, wenn sichergestellt ist, dass Picasa beim andern Benutzer tatsächlich nicht mehr aktiv ist.
Der Autor Wassenhofen berichtet von Fällen, in denen Fotos, deren Dateien auf einem NAS-Laufwerk lagen, bei Bearbeitung mit Picasa dauerhaft unbrauchbar geworden sind. Um dies zu vermeiden, ist anzuraten, alle Fotos und - wie in diesem Artikel beschrieben - die Datenbank auf eine mobile Festplatte hinlänglicher Kapazität zu übertragen und dieser Festplatte auf allen Rechnern den gleichen Laufwerksbuchstaben zuzuordnen, so dass Picasa darauf ohne Netzwerkverbindung zugreifen kann. Wenn außerdem ein NAS-Server vorhanden ist, wäre ratsam, von Zeit zu Zeit eine Kopie dieser Festplatte auf dem NAS-Laufwerk zu sichern. Aber dann sollte nur mit der auf der mobilen Festplatte befindlichen Datenbank gearbeitet werden, die natürlich nicht denselben Laufwerksbuchstaben haben kann wie das NAS-Laufwerk.
Rücksicherung
Wenn die externe Datenbank in ein lokal neu installiertes Picasa übertragen werden soll, starten Sie Picasa auf dem PC nach der Neuinstallation zunächst ohne Fotos und Daten wie oben unter "Eine Batchdatei - unterschiedliche Wirkungen" dargestellt, wobei im Ordner "C:\Users\\AppData\Local\Google" die Unterordner "Picasa2" und "Picasa2Albums" angelegt werden. Danach können die beiden Ordner mit diesen Namen von "M:\Picasa-DB\Appdata\Local\Google" in den genannten lokalen Ordner auf "C:" kopiert werden. Damit steht auch lokal die gleich Datenbankumgebung wieder zur Verfügung.
Festlegung der aktuellen Datenbank
Bei Nutzung von Picasa mit der lokalen Datenbank sollte sich der Anwender auf Suche, Auswahl und Anzeigebeschränken sollte, um diese Datenbank nicht zu verändern. Wenn eine externe Datenbank existiert, dann sollte er Import oder Bearbeitung mit der externen Datenbankumgebung durchführen, die ihm eine ortsunabhängige Bearbeitungsmöglichkeit gibt. Natürlich bleibt es dem Inhaber der Fotos unbenommen, sich dagegen zu entscheiden und die lokale Datenbank aktuell zu halten. Dann allerdings sollte er die externe Nutzung tunlichst auf Suche, Auswahl und Anzeige beschränken. Ihm selbst und den Mitbenutzern sollte klar sein, ob die Nutzung von Picasa den Inhalt der lokalen oder der externen Datenbank verändert oder nicht.
Anhang
Nachfolgend der Inhalt der Beispiel-Batchdatei als kopierbarer Text:
@echo off
set EXTERNPROFILEPATH=M:\Picasa-DB
set PICASAEXECPATH=C:\Program Files (x86)\Google\Picasa3\
set TEMPPATH="%EXTERNPROFILEPATH%\AppData\Local"
if not exist %TEMPPATH% mkdir %TEMPPATH%
if not exist %TEMPPATH% goto NoValidPath
:: Uebergabevariable fuer den Aufruf von Picasa mit dem externen Profil
set USERPROFILE=%EXTERNPROFILEPATH%
:: Pruefung, ob Picasa schon anderswo aufgerufen ist - sonst Sperre einrichten
set LOCKFILE="%EXTERNPROFILEPATH%\PicasaRunning.txt"
if exist %LOCKFILE% goto PicasaRunningAlready
echo Picasa ist schon gestartet von %USERNAME% am %date% um %time% auf Computer %COMPUTERNAME% > %LOCKFILE%
:: Pruefung, ob Installationspfad fuer Picasa zutrifft - ggf. starten, sonst nicht
set TEMPPATH="%PICASAEXECPATH%"
if not exist %TEMPPATH% goto NoValidPath
:: Start Picasa...
echo PICASA wird jetzt im Profil von %EXTERNPROFILEPATH% ausgefuehrt.
echo ACHTUNG:
echo Dieses Fenster muss aktiv bleiben, solange mit PICASA gearbeitet wird;
echo sobald PICASA beendet wird, schliesst es von selbst.
cd %PICASAEXECPATH%
"%PICASAEXECPATH%/Picasa3.exe"
:: Sperrdatei wird beseitigt ...
del %LOCKFILE%
goto eof
:: Picasa ist anderweitig aufgerufen ...
:PicasaRunningAlready
echo Eine anderes Instanz von PICASA ist schon gestartet:
echo %USERNAME% nutzt sie seit %date% um %time% auf %COMPUTERNAME%.
pause
goto eof
:: Fehlermeldung, wenn der Pfad nicht existiert oder nicht erzeugt werden konnte
:NoValidPath
echo FEHLER!
echo Der Pfad %TEMPPATH% ist nicht vorhanden oder konnte nicht erstellt werden.
pause
goto eof |
-
zurück zur Textstelle mit Verweis auf diesen Anhang
Haftungsausschluss
Ich wünsche Ihnen viel Erfolg mit dieser Anleitung. Allerdings übernehme ich keinerlei Gewähr für die Funktionsfähigkeit auf Ihrem Windows-PC, noch hafte ich für irgendwelche Schäden, die durch Verwendung dieser Hinweise auf Ihrem System womöglich entstehen. Ich kann nur versichern, dass bei eigener Implementation auf mehreren verschiedenen Windows-Rechnern keine Probleme aufgetreten sind.
Der englische Mentaltrainer und Autor 
![[Bildkommentar]](http://lh5.ggpht.com/_iK0DTyKQnuI/S5IYiZXBMCI/AAAAAAAAA18/g8f_ez1na-U/s144/FreeOCR3-32.jpg)
Ob Sie nun Schallplatten, Audio-Kassetten oder Mitschnitte von Radiosendungen auf dem PC im verbreiteten mp3-Format aufzeichnen oder solche Aufzeichnungen schneiden möchten, es ist ganz einfach, wenn man weiß wie. - Hier wird Schritt für Schritt beschrieben und veranschaulicht, wie das mit dem Nero WaveEditor geht.